wmi-1.3.16 from opsview.com

2019-02-16 00:16:52 +01:00
parent 163fdd3d1b
commit 17b3af2911
2146 changed files with 678824 additions and 0 deletions
@@ -0,0 +1,138 @@
+dnl -*- mode: m4-mode -*-
+dnl Process this file with autoconf to produce a configure script.
+
+dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
+dnl AC_PREREQ(2.53)
+
+AC_INIT([samba],[],[samba-technical@samba.org])
+
+AC_CONFIG_SRCDIR([include/includes.h])
+AC_CONFIG_HEADER(include/config_tmp.h)
+AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
+
+# Configuration rules.
+m4_include(build/m4/env.m4)
+m4_include(lib/replace/samba.m4)
+m4_include(lib/smbreadline/readline.m4)
+m4_include(heimdal_build/config.m4)
+m4_include(lib/util/fault.m4)
+m4_include(lib/util/signal.m4)
+m4_include(lib/util/util.m4)
+m4_include(lib/util/fsusage.m4)
+m4_include(lib/util/xattr.m4)
+m4_include(lib/util/capability.m4)
+m4_include(lib/util/time.m4)
+m4_include(lib/popt/samba.m4)
+m4_include(lib/charset/config.m4)
+m4_include(lib/socket/config.m4)
+m4_include(lib/talloc/libtalloc.m4)
+m4_include(lib/tdb/libtdb.m4)
+m4_include(lib/ldb/sqlite3.m4)
+m4_include(lib/ldb/libldb.m4)
+m4_include(lib/tls/config.m4)
+m4_include(lib/events/config.m4)
+
+dnl m4_include(auth/kerberos/config.m4)
+
+m4_include(auth/gensec/config.m4)
+m4_include(smbd/process_model.m4)
+m4_include(lib/registry/config.m4)
+m4_include(scripting/swig/config.m4)
+m4_include(ntvfs/posix/config.m4)
+m4_include(ntvfs/unixuid/config.m4)
+m4_include(lib/socket_wrapper/config.m4)
+m4_include(web_server/config.m4)
+m4_include(auth/config.m4)
+m4_include(kdc/config.m4)
+m4_include(ntvfs/sysdep/config.m4)
+m4_include(lib/appweb/config.m4)
+m4_include(nsswitch/config.m4)
+m4_include(libcli/config.m4)
+
+#################################################
+# add *_CFLAGS only for the real build
+CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
+
+#################################################
+# final configure stuff
+
+AC_MSG_CHECKING([configure summary])
+AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
+           AC_MSG_RESULT(yes),
+	   AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
+	   AC_MSG_WARN([cannot run when cross-compiling]))
+
+LIBS=`echo $LIBS | sed -e 's/ *//g'`
+if test x"$LIBS" != x""; then
+	echo "LIBS: $LIBS"
+	AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
+	AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
+	AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
+fi
+
+dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
+LIB_REMOVE_USR_LIB(LDFLAGS)
+LIB_REMOVE_USR_LIB(LIBS)
+
+dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
+CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
+CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
+
+AC_SUBST(ac_default_prefix)
+
+echo "configure: creating build/smb_build/config.pm"
+cat >build/smb_build/config.pm<<CEOF
+# config.pm - Autogenerate by configure. DO NOT EDIT!
+
+package config;
+require Exporter;
+@ISA = qw(Exporter);
+@EXPORT_OK = qw(%enabled %config);
+use strict;
+
+use vars qw(%enabled %config);
+
+%config = (
+CEOF
+
+for ac_var in $ac_subst_vars
+do
+        eval ac_val=\$$ac_var
+        # quote ' (\x27) inside '...' and make sure \ isn't eaten by shells, so use perl:
+        QAC_VAL=$ac_val QAC_VAR=$ac_var perl -e '$myval="$ENV{QAC_VAL}"; $myval =~ s/\x27/\\\x27/g ; print $ENV{QAC_VAR}." => \x27$myval\x27,\n"' >> build/smb_build/config.pm 
+done
+
+cat >>build/smb_build/config.pm<<CEOF
+);
+$SMB_INFO_ENABLES
+1;
+CEOF
+
+
+
+echo "configure: creating config.mk"
+cat >config.mk<<CEOF
+# config.mk - Autogenerated by configure, DO NOT EDIT!
+$SMB_INFO_EXT_LIBS
+$SMB_INFO_SUBSYSTEMS
+$SMB_INFO_LIBRARIES
+CEOF
+
+AC_OUTPUT_COMMANDS(
+[test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && 
+ (cd $builddir; 
+	test -d heimdal || cp -r $srcdir/heimdal $builddir/
+	test -d heimdal_build || cp -r $srcdir/heimdal_build $builddir/
+	test -d build || samba_builddir="$builddir" samba_srcdir="$srcdir" $PERL $srcdir/script/buildtree.pl
+	test -f $builddir/include/smb.h || cp $srcdir/include/smb.h $builddir/include
+ )
+$PERL -I${builddir} -I${srcdir} -I${srcdir}/build ${srcdir}/build/smb_build/main.pl || exit $?],[
+PERL="$PERL";export PERL;export srcdir; export builddir;
+])
+AC_OUTPUT
+
+cmp include/config_tmp.h include/config.h >/dev/null 2>&1
+CMP_RET=$?
+if test $CMP_RET != 0; then
+	cp include/config_tmp.h include/config.h
+fi